# Timeout handler. It sets a global flag to indicate TIMEOUT.
proc event_timeout {} {
  global event_flag
  if {$event_flag eq "WAITING"} {
    set event_flag TIMEOUT
  }
}

# Query ready handler. It sets a global flag to indicate READY.
proc event_result {} {
  global event_flag
  if {$event_flag eq "WAITING"} {
    set event_flag READY
  }
}


# Issue a query with timeout.
#   conn is the database connection handle.
#   sql is the SQL text to execute.
#   timeout is the number of seconds to wait for the query.
# If the query completes, this just displays the row count. In real life,
# you would do something more with the results.
proc query_timeout {conn sql {timeout 20}} {
  global event_flag

  # Calculate timeout in milliseconds:
  set timeout_msec [expr {1000 * $timeout}]

  # Initialize the global flag:
  set event_flag WAITING

  # Establish the result callback:
  pg_result_callback $conn event_result
 
  # Set the alarm clock:
  set after_id [after $timeout_msec event_timeout]

  # Send the query off, but do not wait:
  pg_sendquery $conn $sql

  # Wait for something - timeout or results - to change the global flag:
  vwait event_flag

  # Did the query complete?
  if {$event_flag eq "READY"} {
    # Cancel the alarm clock:
    after cancel $after_id
    puts "Query complete. Fetching result:"
    set res [pg_getresult $conn]
    puts "The query returned [pg_result $res -numTuples] row(s)."
    pg_result $res -clear
  } elseif {$event_flag eq "TIMEOUT"} {
    puts "Query did not complete! It timed out in about $timeout seconds."
    puts "Canceling the request:"
    # Note pg_cancelrequest also cancels the result callback.
    pg_cancelrequest $conn
    # Now we have to block until the backend is ready.
    pg_result [pg_getresult $conn] -clear
    puts "Request canceled."
  }
}